函数参考

_GUICtrlListView_SetColumn

设置列的属性

#Include <GuiListView.au3>
_GUICtrlListView_SetColumn($hWnd, $iIndex, $sText [, $iWidth = -1 [, $iAlign = -1 [, $iImage = -1 [, $fOnRight = False]]]])

参数

$hWnd 控件句柄
$iIndex 列的 0 基索引
$sText 列标题文本
$iWidth [可选参数] 列像素宽度
$iAlign [可选参数] 列标题和列项目文本对齐方式:
0 - 文本左对齐
1 - 文本右对齐
2 - 文本居中
$iImage [可选参数] 图像列表中的图像 0 基索引
$fOnRight [可选参数] 如为 True, 则列图像显示在文字右侧

返回值

成功: 返回 True
失败: 返回 False

注意/说明

None.

相关

_GUICtrlListView_GetColumn, _GUICtrlListView_JustifyColumn

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; 检查传递给 ListView 函数的类名, 设置为真并使用另一控件的句柄可以看出它是否有效

_Main()

Func _Main()
    Local $aInfo, $hListView

    GUICreate("ListView Set Column", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; 添加列
    _GUICtrlListView_AddColumn($hListView, "Column 1", 100)
    _GUICtrlListView_AddColumn($hListView, "Column 2", 100)
    _GUICtrlListView_AddColumn($hListView, "Column 3", 100)

    ; 改变列
    $aInfo = _GUICtrlListView_GetColumn($hListView, 0)
    MsgBox(4160, "信息", "Column 1 Width: " & $aInfo[4])
    _GUICtrlListView_SetColumn($hListView, 0, "New Column 1", 150, 1)
    $aInfo = _GUICtrlListView_GetColumn($hListView, 0)
    MsgBox(4160, "信息", "Column 1 Width: " & $aInfo[4])

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main