函数参考

_GUICtrlListView_SetGroupInfo

设置组信息

#Include <GuiListView.au3>
_GUICtrlListView_SetGroupInfo($hWnd, $iGroupID, $sHeader[, $iAlign = 0[, $iState = $LVGS_NORMAL]])

参数

$hWnd 控件句柄
$iGroupID 组的 ID
$sHeader 标题文本
$iAlign [可选参数] 组标题文本对齐:
0 - 左
1 - 居中
2 - 右
$iState [可选参数] 支持 Vista 及以上系统, 可以有以下值之一:
$LVGS_NORMAL - 展开组,显示组名称及组中全部项目.
$LVGS_COLLAPSED - 折叠组.
$LVGS_HIDDEN - 隐藏组.
$LVGS_NOHEADER - 不显示组标题.
$LVGS_COLLAPSIBLE - 组可以折叠.
$LVGS_FOCUSED - 组拥有键盘焦点.
$LVGS_SELECTED - 组被选中.
$LVGS_SUBSETED - 仅显示部分项目.
$LVGS_SUBSETLINKFOCUSED - 组子集链接有键盘焦点

返回值

成功: 返回 True
失败: 返回 False

注意/说明

 最低操作系统 - Windows XP.

相关

_GUICtrlListView_GetGroupInfo, _GUICtrlListView_GetGroupInfoByIndex

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

$Debug_LV = False ; 检查传递给 ListView 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $aInfo, $hImage, $hListView

    GUICreate("ListView Set Group Info", 400, 300)

    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; 加载图像
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($hListView, $hImage, 1)

    ; 添加列
    _GUICtrlListView_AddColumn($hListView, "Column 1", 100)
    _GUICtrlListView_AddColumn($hListView, "Column 2", 100)
    _GUICtrlListView_AddColumn($hListView, "Column 3", 100)

    ; 添加项目
    _GUICtrlListView_AddItem($hListView, "Row 1: Col 1", 0)
    _GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 2", 1)
    _GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 3", 2)
    _GUICtrlListView_AddItem($hListView, "Row 2: Col 1", 1)
    _GUICtrlListView_AddSubItem($hListView, 1, "Row 2: Col 2", 1)
    _GUICtrlListView_AddItem($hListView, "Row 3: Col 1", 2)

    ; Build groups
    _GUICtrlListView_EnableGroupView($hListView)
    _GUICtrlListView_InsertGroup($hListView, -1, 1, "Group 1", 1)
    _GUICtrlListView_InsertGroup($hListView, -1, 2, "Group 2")
    _GUICtrlListView_SetItemGroupID($hListView, 0, 1)
    _GUICtrlListView_SetItemGroupID($hListView, 1, 2)
    _GUICtrlListView_SetItemGroupID($hListView, 2, 2)

    ; Change group information
    $aInfo = _GUICtrlListView_GetGroupInfo($hListView, 1)
    MsgBox(4160, "信息", "Group 1 Text: " & $aInfo[0])
    _GUICtrlListView_SetGroupInfo($hListView, 1, "New Group 1")

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>_Main