函数参考

_GUICtrlListView_SetImageList

分配图像列表到控件

#Include <GuiListView.au3>
_GUICtrlListView_SetImageList($hWnd, $hHandle[, $iType = 0])

参数

$hWnd 控件句柄
$hHandle 图像列表句柄
$iType [可选参数] 图像列表类型:
0 - 大图标图像列表
1 - 小图标图像列表
2 - 状态图像图像列表

返回值

成功: 返回先前图像列表句柄
失败: 返回 0

注意/说明

 当前图像列表将被销毁时,控件也被销毁;除非你设置了 $LVS_SHAREIMAGELISTS 样式.
 如果您使用此信息来代替一个图像列表,其他应用程序必须明确地销毁所有图像列表,
 除当前应用的图像列表之外.

相关

_GUICtrlListView_GetImageList

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

$Debug_LV = False ; 检查传递给 ListView 函数的类名, 设置为真并使用另一控件的句柄可以看出它是否有效

_Main()

Func _Main()
    Local $hImage, $hListView

    GUICreate("ListView Set Image List", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; 加载图像
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
    Local $hPrevImageList = _GUICtrlListView_SetImageList($hListView, $hImage, 1)

    MsgBox(4160, "信息", "Previous Image List Handle: 0x" & Hex($hPrevImageList) & @CRLF & _
            "IsPtr = " & IsPtr($hPrevImageList) & " IsHWnd = " & IsHWnd($hPrevImageList))

    ; 添加列
    _GUICtrlListView_AddColumn($hListView, "Column 1", 100)
    _GUICtrlListView_AddColumn($hListView, "Column 2", 100)
    _GUICtrlListView_AddColumn($hListView, "Column 3", 100)

    ; 添加项目
    _GUICtrlListView_AddItem($hListView, "Item 1", 0)
    _GUICtrlListView_AddItem($hListView, "Item 2", 1)
    _GUICtrlListView_AddItem($hListView, "Item 3", 2)

    ; 获取图像列表句柄
    MsgBox(4160, "信息", "Image List Handle: 0x" & Hex(_GUICtrlListView_GetImageList($hListView, 1)))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main