函数参考

_GUICtrlListView_SetItemChecked

设置选中状态

#Include <GuiListView.au3>
_GUICtrlListView_SetItemChecked($hWnd, $iIndex[, $fCheck = True])

参数

$hWnd 控件句柄
$iIndex 项目的 0 基索引;-1,应用全部项目
$fCheck [可选参数] 选中状态标志值:
True - 选中
False - 非选中

返回值

成功: 返回 True
失败: 返回 False

注意/说明

 仅在控件有 $LVS_EX_CHECKBOXES 扩展样式时有效

相关

_GUICtrlListView_GetItemChecked

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; 检查传递给 ListView 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $exStyles = BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES), $hListView

    GUICreate("ListView Set Item Checked State", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    _GUICtrlListView_SetExtendedListViewStyle($hListView, $exStyles)
    GUISetState()

    ; 添加列
    _GUICtrlListView_AddColumn($hListView, "Column 1", 100)
    _GUICtrlListView_AddColumn($hListView, "Column 2", 100)
    _GUICtrlListView_AddColumn($hListView, "Column 3", 100)

    ; 添加项目
    _GUICtrlListView_AddItem($hListView, "Row 1: Col 1", 0)
    _GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 2", 1)
    _GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 3", 2)
    _GUICtrlListView_AddItem($hListView, "Row 2: Col 1", 1)
    _GUICtrlListView_AddSubItem($hListView, 1, "Row 2: Col 2", 1)
    _GUICtrlListView_AddItem($hListView, "Row 3: Col 1", 2)

    ; Check item 2
    _GUICtrlListView_SetItemChecked($hListView, 1)
    MsgBox(4160, "信息", "Item 2 Checked: " & _GUICtrlListView_GetItemChecked($hListView, 1))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main