函数参考

_GUICtrlListView_SetItemSelected

设置项目是否被选中

#Include <GuiListView.au3>
_GUICtrlListView_SetItemSelected($hWnd, $iIndex[, $fSelected = True[, $fFocused = False]])

参数

$hWnd 控件句柄
$iIndex 项目的 0 基索引, -1, 则设置所有项目的选定状态
$fSelected [可选参数] 如果为 True, 项目被选中,否则不是.
$fFocused [可选参数] 如果 True,项目具有焦,否则不是.

返回值

成功: 返回 True
失败: 返回 False

注意/说明

None.

相关

_GUICtrlListView_GetItemSelected

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; 检查传递给 ListView 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hListView

    GUICreate("ListView Set Item Selected", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; 添加列
    _GUICtrlListView_AddColumn($hListView, "Items", 100)

    ; 添加项目
    _GUICtrlListView_AddItem($hListView, "Item 1")
    _GUICtrlListView_AddItem($hListView, "Item 2")
    _GUICtrlListView_AddItem($hListView, "Item 3")

    ; Select item 2
    _GUICtrlListView_SetItemSelected($hListView, 1)
    MsgBox(4160, "信息", "Item 2 Selected: " & _GUICtrlListView_GetItemSelected($hListView, 1))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main