函数参考

_GUICtrlListView_SetView

设置控件的视图

#Include <GuiListView.au3>
_GUICtrlListView_SetView($hWnd, $iView)

参数

$hWnd 控件句柄
$iView 视图状态:
0 - 报表视图
1 - 大图标
2 - 列表视图
3 - 小图标
4 - 平铺显示

返回值

成功: 返回 True
失败: 返回 False

注意/说明

 最低操作系统 - Windows XP.

相关

_GUICtrlListView_GetView

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; 检查传递给 ListView 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hListView

    GUICreate("ListView Set View", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; 添加列
    _GUICtrlListView_AddColumn($hListView, "Items", 100)

    ; 添加项目
    _GUICtrlListView_BeginUpdate($hListView)
    For $iI = 1 To 10
        _GUICtrlListView_AddItem($hListView, "Item " & $iI)
    Next
    _GUICtrlListView_EndUpdate($hListView)

    ; Set view
    MsgBox(4160, "信息", "View: " & _GUICtrlListView_GetView($hListView))
    _GUICtrlListView_SetView($hListView, 4)
    MsgBox(4160, "信息", "View: " & _GUICtrlListView_GetView($hListView))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main