函数参考

_GUICtrlMonthCal_GetMinReqRect

检索显示完整月历所需的最低尺寸

#Include <GuiMonthCal.au3>
_GUICtrlMonthCal_GetMinReqRect($hWnd)

参数

$hWnd 控件句柄

返回值

成功: 返回 $tagRECT 结构

注意/说明

None.

相关

_GUICtrlMonthCal_GetMinReqHeight, _GUICtrlMonthCal_GetMinReqWidth, $tagRECT

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>

$Debug_MC = False ; Check ClassName being passed to MonthCal functions, set to True and use a handle to another control to see it work

Global $iMemo

_Main()

Func _Main()
    Local $tRect, $hMonthCal

    ; 创建 GUI
    GUICreate("Month Calendar Get Min Req Rect", 400, 300)
    $hMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, BitOR($WS_BORDER, $MCS_MULTISELECT), 0x00000000)

    ; 创建 memo 控件
    $iMemo = GUICtrlCreateEdit("", 4, 168, 392, 128, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Get minimum required height/width
    $tRect = _GUICtrlMonthCal_GetMinReqRect($hMonthCal)
    MemoWrite("Minimum required height: " & DllStructGetData($tRect, "Bottom"))
    MemoWrite("Minimum required width : " & DllStructGetData($tRect, "Right"))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; 写入消息到 memo
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite