函数参考

_GUICtrlMonthCal_GetMonthRangeMinStr

检索控件日期显示范围的下限值格式字符串

#Include <GuiMonthCal.au3>
_GUICtrlMonthCal_GetMonthRangeMinStr($hWnd[, $sFormat = "%02d/%02d/%04d"])

参数

$hWnd 控件句柄
$sFormat [可选参数] 用于格式化日期的格式字符串

返回值

成功: 返回格式化的日期

注意/说明

None.

相关

_GUICtrlMonthCal_GetMonthRangeMin

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>

$Debug_MC = False ; 检查传递给 MonthCal 函数的类名, 设置为真并使用另一控件的句柄可以看出它是否有效

Global $iMemo

_Main()

Func _Main()
    Local $hMonthCal

    ; 创建 GUI
    GUICreate("Month Calendar Get Month Range Min String", 400, 300)
    $hMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, BitOR($WS_BORDER, $MCS_MULTISELECT), 0x00000000)

    ; 创建 memo 控件
    $iMemo = GUICtrlCreateEdit("", 4, 168, 392, 128, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 获取月份范围
    MemoWrite("Month range minimum: " & _GUICtrlMonthCal_GetMonthRangeMinStr($hMonthCal))
    MemoWrite("Month range maximum: " & _GUICtrlMonthCal_GetMonthRangeMaxStr($hMonthCal))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; 写入消息到 memo
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite