函数参考

_GUICtrlRebar_AddToolBarBand

添加带区控件.(附带工具栏)

#Include <GuiRebar.au3>
_GUICtrlRebar_AddToolBarBand($hwndRebar, $hwndToolbar[, $sText = ""[, $iIndex = -1[, $fStyle = -1]]])

参数

$hwndRebar 伸缩条控件句柄
$hwndToolbar 工具栏句柄
$sText [可选参数] 带区文本
$iIndex [可选参数] 带区插入的 0 索引位置
如果此参数设置为 -1,带区将添加到最后位置
$fStyle [可选参数] 带区样式标志.此值可以是以下组合:
$RBBS_BREAK - 带区在新行.
$RBBS_CHILDEDGE - 带区是一个有顶部和底部边缘的子窗口.
$RBBS_FIXEDBMP - 带区调整大小时,不移动背景位图.
$RBBS_FIXEDSIZE - 带区不能调整大小. 在此样式中, 带区不显示控制尺寸
$RBBS_GRIPPERALWAYS - 版本 4.71. 带区具有尺寸控制, 即使伸缩条上仅有一个带区.
$RBBS_HIDDEN - 带区不可见.
$RBBS_NOGRIPPER - 版本 4.71. 带区没有尺寸控制, 即使伸缩条上有多个带区.
$RBBS_USECHEVRON - 版本 5.80. 当带区小于 cxIdeal 时显示一个 (∧) 上尖号或下尖号 (∨).
$RBBS_VARIABLEHEIGHT - 版本 4.71. 带区可由伸缩条改变大小;cyIntegral 与 cyMaxChild 将影响伸缩条如何调整带区.
$RBBS_NOVERT - 垂直时不显示.
$RBBS_USECHEVRON - 显示下拉按钮.
$RBBS_HIDETITLE - 阻止带区标题隐藏.
$RBBS_TOPALIGN - 带区置于顶行.

返回值

成功: 返回 True
失败: 返回 False

注意/说明

None.

相关

_GUICtrlRebar_AddBand, _GUICtrlRebar_DeleteBand

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiReBar.au3>
#include <GuiToolbar.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_RB = False

_Main()

Func _Main()
    Local $hgui, $btnExit, $hToolbar, $hReBar, $hInput
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    $hgui = GUICreate("Rebar", 400, 396, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_MAXIMIZEBOX))

    ; create the rebar control
    $hReBar = _GUICtrlRebar_Create($hgui, BitOR($CCS_TOP, $WS_BORDER, $RBS_VARHEIGHT, $RBS_AUTOSIZE, $RBS_BANDBORDERS))

    ; create a toolbar to put in the rebar
    $hToolbar = _GUICtrlToolbar_Create($hgui, BitOR($TBSTYLE_FLAT, $CCS_NORESIZE, $CCS_NOPARENTALIGN))

    ; 添加标准系统位图
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; 添加按钮
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; create a input box to put in the rebar
    $hInput = GUICtrlCreateInput("Input control", 0, 0, 120, 20)

    ;add band containing the control
    _GUICtrlRebar_AddBand($hReBar, GUICtrlGetHandle($hInput), 120, 200, "Name:")

    ; add band containing the control to begining of rebar
    _GUICtrlRebar_AddToolBarBand($hReBar, $hToolbar, "", 0)

    $btnExit = GUICtrlCreateButton("Exit", 150, 360, 100, 25)
    GUISetState(@SW_SHOW)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $btnExit
                Exit
        EndSwitch
    WEnd
EndFunc   ;==>_Main