函数参考

_GUICtrlRichEdit_AutoDetectURL

启用或禁用自动检测网址(URL)

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_AutoDetectURL($hWnd, $fState)

参数

$hWnd 控件句柄
$fState 设为 True, 则检测 URL 的文本, False 则不检测

返回值

成功: 返回 True
失败: 返回 False,设置@error:
@error: 101 - $hWnd 参数值不是句柄
102 - $fState 参数值既不是 True 也不是 False
700 - 内部错误, 例如:内存不足

注意/说明

 如果启用,任何修改的文本都作为扫描网址的匹配文本.
 并识别以下字符串开始的网址:
 http:, file:, mailto:, ftp:, https:, gopher:, nntp:, prospero:,telnet:, news:, wais:.
 当检测到一个 URL 时,Windows 设置 URL 字符串的所有字符连接属性,并高亮显示该字符串.
 当自动检测网址和已检测到网址时,
 Windows 将删除没有网址的所有字符链接属性
 对于发生的通知,与 $ENM_LINK 一起调用 _GUICtrlRichEdit_SetEventMask $ENM_LINK

相关

_GUICtrlRichEdit_SetEventMask

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    GUISetState()

    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
    _GUICtrlRichEdit_SetEventMask($hRichEdit, $ENM_LINK)

    _GUICtrlRichEdit_AutoDetectURL($hRichEdit, True)
    _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "http://www.autoitscript.com")
    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
        EndSelect
    WEnd
EndFunc   ;==>Main

Func WM_NOTIFY($hWnd, $iMsg, $iWparam, $iLparam)
    #forceref $hWnd, $iMsg, $iWparam
    Local $hWndFrom, $iCode, $tNMHDR, $tEnLink, $cpMin, $cpMax, $tMsgFilter
    $tNMHDR = DllStructCreate($tagNMHDR, $iLparam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hRichEdit
            Select
                Case $iCode = $EN_LINK
                    $tMsgFilter = DllStructCreate($tagMSGFILTER, $iLparam)
                    If DllStructGetData($tMsgFilter, "msg") = $WM_LBUTTONUP Then
                        $tEnLink = DllStructCreate($tagENLINK, $iLparam)
                        $cpMin = DllStructGetData($tEnLink, "cpMin")
                        $cpMax = DllStructGetData($tEnLink, "cpMax")
                        MsgBox(4096, "", "Invoke your web browser here and point it to " & _
                                _GUICtrlRichEdit_GetTextInRange($hRichEdit, $cpMin, $cpMax))
                    EndIf
            EndSelect
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY