函数参考

_GUICtrlRichEdit_Destroy

删除 RichEdit 控件

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_Destroy(ByRef $hWnd)

参数

$hWnd 控件句柄

返回值

成功: 返回 True, 句柄设置为 0
失败: 返回 0,设置@error:
@error: 1 - 试图破坏属于另一个应用程序的控件

注意/说明

只能用于 _GUICtrlRichEdit_Create 创建的 RichEdit 控件

相关

_GUICtrlRichEdit_Create

示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $btnDoIt
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $btnDoIt = GUICtrlCreateButton("Do it", 10, 260, 90, 25)

    GUISetState()

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                GUIDelete() ; needed unless script crashes if DoIt as not been pushed
                Exit
            Case $iMsg = $btnDoIt
                _GUICtrlRichEdit_Destroy($hRichEdit)
        EndSelect
    WEnd
EndFunc   ;==>Main