函数参考

_GUICtrlRichEdit_FindTextInRange

搜索字符区间范围内的文本

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_FindTextInRange($hWnd, $sText [, $iStart = 0 [, $iEnd = -1 [, $fMatchCase = False [, $fwholeWord = False [, $iBehavior = 0]]]]])

参数

$hWnd 控件句柄
$sText 搜索的文本
$iStart [可选参数] 字符区间搜索的起始位置
默认 : 控件的起点
$iEnd [可选参数] 字符区间搜索的结束位置
默认 : 控件的结束点
$fMatchCase [可选参数] 是否区分大小写
默认 : 不区分大小写
$fWholeWord [可选参数] 搜索完整单词
默认 : 部分或全部字
$iBehavior [可选参数] 任何 BitOr 组合: $FR_MATCHALEFHAMZA, $FR_MATCHDIAC 与 $FR_MATCHKASHIDA
默认 : 0

返回值

成功: 返回值在 array[2] 内
如果找到目标字符串, 返回匹配文本在字符区间范围内的位置值, 例如:[45, 52]
如果没有找到,则返回 [-1, -1]
失败: 返回 0,设置@error:
@error: 101 - $hWnd 参数值不是句柄
102 - $sText = ""
103 - $iStart 既不是正数或零, 也不是 -1
104 - $iEnd 既不是正数或零, 也不是 -1
105 - $fMatchCase 必须是 True 或 False
106 - $fwholeWord 必须是 True 或 False
1071 - $iBehavior 不是一个数字
1072 - $iBehavior 无效

注意/说明

 控件的起点为字符区间范围的 0 位置.
 默认字符范围,0 到 -1,搜索整个范围的文字.
 设置 $iEnd 为 -1,表示向下搜索到控件的尾部.
 设置 $iStart 为 -1,表示向上搜索到控件的起始位置.

相关

_GUICtrlRichEdit_FindText

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $ai
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    GUISetState()

    _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "This is appended text.")

    $ai = _GUICtrlRichEdit_FindTextInRange($hRichEdit, "test", 20, 6)
    Report('"test" found between inter-character positions ' & $ai[0] & " and " & $ai[1])

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    GUICtrlSetData($lblMsg, $sMsg)
EndFunc   ;==>Report