函数参考

_GUICtrlRichEdit_GetCharPosOfPreviousWord

获取上一个单词之前的字符区间位置

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetCharPosOfPreviousWord($hWnd, $iCpStart)

参数

$hWnd 控件句柄
$iCPStart 字符区间的开始位置

返回值

成功: 返回上一个单词之前的字符区间位置
失败: 返回 0,设置@error:
@error: 101 - $hWnd 参数值不是句柄
102 - $iCpStart 不是一个数字

注意/说明

 单词的定义较广泛,它包括标点符号,括号和连字符.

相关

_GUICtrlRichEdit_GetCharPosOfNextWord, _GUICtrlRichEdit_GetCharWordBreakInfo

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iCp = 200
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    _GUICtrlRichEdit_AppendText($hRichEdit, "AutoIt v3 is a freeware BASIC-like scripting language designed for " _
             & "automating the Windows GUI and general scripting.")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iCp = _GUICtrlRichEdit_GetCharPosOfPreviousWord($hRichEdit, $iCp)
                GUICtrlSetData($lblMsg, $iCp)
                ControlFocus($hRichEdit, "", "")
                _GUICtrlRichEdit_GotoCharPos($hRichEdit, $iCp)
        EndSelect
    WEnd
EndFunc   ;==>Main