函数参考

_GUICtrlRichEdit_GetLineCount

检索多行编辑控件的行数

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetLineCount($hWnd)

参数

$hWnd 控件句柄

返回值

成功: 控件的文本总行数
失败: 返回 0, 并设置 @error:
@error: 101 - $hWnd 参数值不是句柄

注意/说明

 不包含任何文本的控件会有一行

 行数不包括目前的可见行

 如果启用了自动换行,当编辑窗口的尺寸变化时,行数也可以改变.

相关

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    GUISetState()

    For $i = 2 To 10
        _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "Line " & $i)
    Next

    Report("The control contains " & _GUICtrlRichEdit_GetLineCount($hRichEdit) & " lines")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    GUICtrlSetData($lblMsg, $sMsg)
EndFunc   ;==>Report