函数参考

_GUICtrlRichEdit_GetLineNumberFromCharPos

检索字符区间位置的行数

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetLineNumberFromCharPos($hWnd, $iCharPos)

参数

$hWnd 控件句柄
$iCharPos 字符区间位置

返回值

成功: 返回基于 1 的行数
失败: 返回 0,设置@error:
@error: 101 - $hWnd 参数值不是句柄
102 - $iCharPos 参数值不是正数

注意/说明

 不包含任何文本的控件会有一行.
 控件字符区间的第一个位置为 0.
 第一行是 1 号行.
 如果 $iCharPos 为负,或大于控件中的字符数,
 则返回控件的行数.

相关

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    GUISetState()

    _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "This is appended text")
    Report("Inter-character position 30 is on line " & _GUICtrlRichEdit_GetLineNumberFromCharPos($hRichEdit, 30))

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    GUICtrlSetData($lblMsg, $sMsg)
EndFunc   ;==>Report