获取获取(第一)选定的;或者如果没有选择时的当前段落的明暗处理
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaShading($hWnd)
| $hWnd | 控件句柄 |
| 成功: | 返回第一选定段落的由分号 (;} 分隔的设置字符串值 (:): |
| 值 1 - 深浅度 - 前景色的百分比, 其余为背景色 | |
| 值 2 - 类型 - 包含下列值之一的字符串: | |
| non - 无 | |
| dhz - 暗水平线 | |
| dvt - 暗垂直线 | |
| ddd - 暗下对角线 | |
| dud - 暗上对角线 | |
| dgr - 暗栅格 | |
| dtr - 暗网格 | |
| lhz - 亮水平线 | |
| lvt - 亮垂直线 | |
| ldd - 亮下对角线 | |
| lud - 亮上对角线 | |
| lgr - 亮栅格 | |
| ltr - 亮网格 | |
| 值 3 - 前景色 - 下列值之一: | |
| "blk" - 黑色 | |
| "blu" - 蓝色 | |
| "cyn" - 青色 | |
| "grn" - 绿色 | |
| "mag" - 紫色 | |
| "red" -红 | |
| "yel" -黄 | |
| "whi" - 白色 | |
| "dbl" - 暗蓝 | |
| "dgn" - 暗绿 | |
| "dmg" - 暗紫 | |
| "drd" - 暗红 | |
| "dyl" - 暗黄 | |
| "dgy" - 暗灰 | |
| "lgy" - 亮灰 | |
| 值 4 - 背景颜色 - 使用与前景颜色相同的值 | |
| 值 5 - 范围: | |
| a - 所有(或使用的)选定的段落进行这些设置 | |
| f - 第一选定使用这些设置,但其它不使用 | |
| c - 当前段落使用这些设置 | |
| 失败: | 返回 "" ,设置 @error |
| @error: | 101 - $hWnd 参数值不是句柄 |
在MSDN中搜索
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $iMsg, $btnNext, $iStep = 0
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState()
_GUICtrlRichEdit_SetText($hRichEdit, "First paragraph")
Report("0. Para with default settings")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~ GUIDelete() ; 同样行
Exit
Case $iMsg = $btnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
_GUICtrlRichEdit_SetParaShading($hRichEdit, 60, "ddd", "blu", "dmg")
Report("1. Shading of second paragraph is ")
Case 2
_GUICtrlRichEdit_SetSel($hRichEdit, 0, 2)
Report("2. Style of first paragraph in the selection is ")
Case 3
_GUICtrlRichEdit_SetSel($hRichEdit, 10, 26)
_GUICtrlRichEdit_SetParaShading($hRichEdit, Default, "dgr")
Report("3. Change shading of both paragraphs")
Case 4
; 把所有的文本流保存到桌面,这样您可以在 Word 中查看设置.
_GUICtrlRichEdit_Deselect($hRichEdit)
_GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Main
Func Report($sMsg)
$sMsg = $sMsg & @CR & @CR & "Get function returns " & @CR & _GUICtrlRichEdit_GetParaShading($hRichEdit)
GUICtrlSetData($lblMsg, $sMsg)
ControlFocus($hRichEdit, "", "")
EndFunc ;==>Report