获取(第一)选定段落;或者没有选择时的当前段落的间距设置
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaSpacing($hWnd)
| $hWnd | 控件句柄 |
| 成功: | 返回由分号(;)分隔的设置值字符串: |
| 值 1 - 相互 - 行间距: | |
| 一个数字- 空间单位 | |
| 或 " | |
| lines" - 行 | |
| 值 2 - 范围值 1: | |
| a - 所有(或使用得)选定段有上面的设置 | |
| f - 第一段落选择有此设置,其它没有 | |
| c - 当前段落有此设置 | |
| 值 3 - 段前间距 (空间单位) | |
| 值 4 - 范围值 3 - 见上面 | |
| 值 5 - 段后间距 (空间单位) | |
| 值 6 - 范围值 5 - 见上面 | |
| 失败: | 返回 "" ,设置@error |
| @error: | 101 - $hWnd 参数值不是句柄 |
在MSDN中搜索
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $iMsg, $btnNext, $iStep = 0
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState()
_GUICtrlRichEdit_SetText($hRichEdit, "First paragraph")
Report("0. Para with default settings")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~ GUIDelete() ; 同样行
Exit
Case $iMsg = $btnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
_GUICtrlRichEdit_SetParaSpacing($hRichEdit, "2 lines", .2, .25)
Report("1. Spacing of second paragraph is ")
Case 2
_GUICtrlRichEdit_SetSel($hRichEdit, 0, 2)
Report("2. Settings of first paragraph in the selection are ")
Case 3
_GUICtrlRichEdit_SetSel($hRichEdit, 10, 26)
_GUICtrlRichEdit_SetParaSpacing($hRichEdit, Default, .1)
Report("3. Change spacing of both paragraphs")
Case 4
; Stream all text to the Desktop so you can look at Indents settings in Word
_GUICtrlRichEdit_Deselect($hRichEdit)
_GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Main
Func Report($sMsg)
$sMsg = $sMsg & @CR & @CR & "Get function returns " & @CR & _GUICtrlRichEdit_GetParaSpacing($hRichEdit)
GUICtrlSetData($lblMsg, $sMsg)
ControlFocus($hRichEdit, "", "")
EndFunc ;==>Report