函数参考

_GUICtrlRichEdit_GetText

获取控件中的全部文本

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetText($hWnd [, $fCrToCrLf = False [, $iCodePage = 0 [, $sReplChar = ""]]])

参数

$hWnd 控件句柄
$fCrToCrLf [可选参数] 是否每个 CR 转换为 CRLF
True - 是
False - 否(默认)
$iCodePage [可选参数] 用于转换的代码页
默认 : 使用系统默认
CP_ACP 位 ANSI 代码页, 1200 为 Unicode 代码页
$sReplChar [可选参数] 如果 $iCodePage 不是 1200,
且宽字符无法以指定代码页代替时,指定使用的字符

返回值

成功: 返回文本
失败: 返回 "" ,设置@error
@error: 101 - $hWnd 参数值不是句柄
102 - $fCrToCrLf 必须是 True 或 False
103 - $iCodePage 不是一个数字
700 - 内部错误

注意/说明

 成功时, 如果设置了 $sReplChar, @extended 包含字符是否被使用
 调用 _GUICtrlRichEdit_IsModified() 确定文本是否发生了变化

相关

_GUICtrlRichEdit_SetText, _GUICtrlRichEdit_AppendText, _GUICtrlRichEdit_InsertText, _GUICtrlRichEdit_IsModified

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $hRichEdit, $iMsg
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    GUISetState()

    _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "This is appended text.")

    Report("Text Appended: " & @CR & @CR & _GUICtrlRichEdit_GetText($hRichEdit))

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    GUICtrlSetData($lblMsg, $sMsg)
EndFunc   ;==>Report