函数参考

_GUICtrlRichEdit_GetTextInLine

获取一行文本

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetTextInLine($hWnd, $iLine)

参数

$hWnd 控件句柄
$iLine 行号

返回值

成功: 返回文本
失败: 返回 False,设置@error
@error: 101 - $hWnd 参数值不是句柄
1021 - $iLine 参数值不是正数
1022 - $iLine 超过控件行总数
700 - 内部错误

注意/说明

 控件的的第一行是 1

相关

_GUICtrlRichEdit_GetTextInRange, _GUICtrlRichEdit_GetSel

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    GUISetState()

    _GUICtrlRichEdit_SetText($hRichEdit, "This is a test." & @CR & "More text in another line")
    Report(_GUICtrlRichEdit_GetTextInLine($hRichEdit, 1))

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    GUICtrlSetData($lblMsg, $sMsg)
EndFunc   ;==>Report