函数参考

_GUICtrlRichEdit_GetXYFromCharPos

检索字符区间位置的 X、Y 坐标

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetXYFromCharPos($hWnd, $iCharPos)

参数

$hWnd 控件句柄
$iCharPos 字符区间位置

返回值

成功: 返回数组 [
, ] - 字符区间位置坐标值相对于客户区左上角
失败: 设置@error
@error: 101 - $hWnd 参数值不是句柄
1021 - $iCharPos 既不是正数或零,
1022 - $iCharPos 超过控件中的字符数

注意/说明

 第一个字符区间位置的编号为 0
 对于多行控件,即使字符区间位置不可见,也能返回坐标.

相关

_GUICtrlRichEdit_GetCharPosFromXY

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $hRichEdit, $iMsg, $ai, $btnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "This is appended text.")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        $ai = _GUICtrlRichEdit_GetXYFromCharPos($hRichEdit, 20)
                        Report("1.The coordinates of inter-character position 20 are (" & $ai[0] & "," & $ai[1] & ")")
                    Case 2
                        Report("2.The inter-character position at or nearest coordinates (" & $ai[0] & "," & $ai[1] & ") is " & _
                                _GUICtrlRichEdit_GetCharPosFromXY($hRichEdit, $ai[0], $ai[1]))
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    GUICtrlSetData($lblMsg, $sMsg)
EndFunc   ;==>Report