函数参考

_GUICtrlRichEdit_SetBkColor

设置控件的背景颜色

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetBkColor($hWnd [, $iColor = Default])

参数

$hWnd 控件句柄
$iColor [可选参数] 滚动类型:
COLORREF 值
关键字 Default - 系统颜色(默认)

返回值

成功: 返回 True
失败: 返回 False,设置@error
@error: 101 - $hWnd 参数值不是句柄
1022 - $iColor 无效

注意/说明

If you need to create a COLORREF value from an color array use _ColorSetCOLORREF() not _ColorSetRGB().

相关

_GUICtrlRichEdit_GetBkColor

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Color.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    _GUICtrlRichEdit_SetText($hRichEdit, "Paragraph 1")
    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetBkColor($hRichEdit, 0xE8CCCC)
                        Report("1. Colored background")
                    Case 2
                        _GUICtrlRichEdit_SetBkColor($hRichEdit)
                        Report("2. Back to white")
                    Case 3
                        _GUICtrlRichEdit_SetBkColor($hRichEdit, 0xB3B3C7)
                        Report("3. Colored background again")
                        ; 把所有的文本流保存到桌面,这样您可以在 Word 中查看设置.
                        _GUICtrlRichEdit_Deselect($hRichEdit)
                        _GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    Local $iBngColor = _GUICtrlRichEdit_GetBkColor($hRichEdit)
    Local $aRet = _ColorGetRGB($iBngColor)
    $sMsg = $sMsg & @CR & @CR & $aRet[0] & ";" & $aRet[1] & ";" & $aRet[2] & " BngColor=0x" & Hex($iBngColor)
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report