函数参考

_GUICtrlRichEdit_SetFont

设置选定文本(或者没有选定时,设置插入点插入文本) 的字体属性

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetFont($hWnd [, $iPoints = Default [, $sName = Default [, $iCharset = Default [, $iLcid = Default]]]])

参数

$hWnd 控件句柄
$iPoints [可选参数] 磅值(注:1 磅=1/72 英寸)大小
$sName [可选参数] 字体的名称, 例如: "Courier" not "Courier Bold"
$iCharSet [可选参数] 字符集:
$ANSI_CHARSET - 0
$BALTIC_CHARSET - 186
$CHINESEBIG5_CHARSET - 136
$DEFAULT_CHARSET - 1
$EASTEUROPE_CHARSET - 238
$GB2312_CHARSET - 134
$GREEK_CHARSET - 161
$HANGEUL_CHARSET - 129
$MAC_CHARSET - 77
$OEM_CHARSET - 255
$RUSSIAN_CHARSET - 204
$SHIFTJIS_CHARSET - 128
$SYMBOL_CHARSET - 2
$TURKISH_CHARSET - 162
$VIETNAMESE_CHARSET - 163
$iLcid [可选参数] 见 http://www.microsoft.com/globaldev/reference/lcid-all.mspx

返回值

成功: 返回 True
失败: 返回 False,设置@error
@error: 101 - $hWnd 参数值不是句柄
102 - $iPoints 参数值不是正数
103 - $sName 不是一个文本
104 - $iCharSet 不是一个数字
105 - $iLcid 不是一个数字

注意/说明

如果参数被省略(或着Default),则该值不变

相关

_GUICtrlRichEdit_GetFont, _GUICtrlRichEdit_ChangeFontSize

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        Report("1. Initial")
                    Case 2
                        _GUICtrlRichEdit_SetFont($hRichEdit, 15, "Times Roman")
                        Report("2. Set Font")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    Local $aRet = _GUICtrlRichEdit_GetFont($hRichEdit)
    $sMsg = $sMsg & @CR & @CR & $aRet[1] & " " & $aRet[0] & " points"
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report