函数参考

_GUICtrlRichEdit_SetLimitOnText

修改可以键入的字符数,粘贴或将流(streamed)作为 Rich 文本格式

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetLimitOnText($hWnd, $iNewLimit)

参数

$hWnd 控件句柄
$iNewLimit 新的限制

返回值

成功: 返回 True
失败: 返回 False设置@error
@error: 101 - $hWnd 参数值不是句柄
102 - $iNewLimit 既不是正数或零,

注意/说明

 函数为控件设置用户可键入或粘贴的字符数量.
 这也限制了对 RTF 格式文本的字符数,以及可以由流使用的
 _GUICtrlRichEdit_StreamFromFile and _GUICtrlRichEdit_StreamFromVar.
 它不限制流中的纯文本数量.
 初始限额为 32,767 个字符.

相关

_GUICtrlRichEdit_StreamToFile, _GUICtrlRichEdit_StreamToVar

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    _GUICtrlRichEdit_SetText($hRichEdit, "Paragraph 1")
    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetLimitOnText($hRichEdit, 0)
                        GUICtrlSetData($lblMsg, "1. Limit set to 65,536 characters")
                    Case 2
                        _GUICtrlRichEdit_SetLimitOnText($hRichEdit, 100000)
                        GUICtrlSetData($lblMsg, "2. Limit set to 100,000 characters")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main