函数参考

_GUICtrlRichEdit_SetParaSpacing

设置(第一)当前选择(或没有选择时的插入点所在段落)的段落间距

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetParaSpacing($hWnd, [$vInter=Default [, $iBefore=Default [, $iAfter=Default]]])

参数

$hWnd 控件句柄
$vInter [可选参数] 行与行之间的间距:
任意: 数字 - 空间单位
或: "<数字>行" - 一行
$iBefore [可选参数] 段落前间距(空间单位)
$iAfter [可选参数] 段落后间距 (空间单位)

返回值

成功: 返回 True
失败: 返回 False,并设置@error
@error: 101 - $hWnd 不是一个句柄.
103 - $iBefore 不是正数,也不是 0.
104 - $iAfter 不是正数,也不是 0.
1021 - $vInter 无效
1022 - 只有 1, 1.5 与 2 可以通过 "行" 设置间距

注意/说明

只是在需要使用非默认值时才设置

调用 _GUICtrlRichEdit_SetSpaceUnit 函数设置 "空间单位". 最初为英寸

相关

_GUICtrlRichEdit_GetParaSpacing, _GUICtrlRichEdit_SetSpaceUnit

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    _GUICtrlRichEdit_SetText($hRichEdit, "First paragraph")
    Report("0. Para with default settings")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
                        _GUICtrlRichEdit_SetParaSpacing($hRichEdit, "2 lines", .2, .25)
                        Report("1. Spacing of second paragraph is ")
                    Case 2
                        _GUICtrlRichEdit_SetSel($hRichEdit, 0, 2)
                        Report("2. Settings of first paragraph in the selection are ")
                    Case 3
                        _GUICtrlRichEdit_SetSel($hRichEdit, 10, 26)
                        _GUICtrlRichEdit_SetParaSpacing($hRichEdit, Default, .1)
                        Report("3. Change spacing of both paragraphs")
                    Case 4
                        ; Stream all text to the Desktop so you can look at Indents settings in Word
                        _GUICtrlRichEdit_Deselect($hRichEdit)
                        _GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    $sMsg = $sMsg & @CR & @CR & "Get function returns " & @CR & _GUICtrlRichEdit_GetParaSpacing($hRichEdit)
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report