函数参考

_GUICtrlRichEdit_SetPasswordChar

设置代替用户输入文本显示的密码字符

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetPasswordChar($hWnd[, $cDisplayChar = "0"])

参数

$hWnd 控件句柄
$cDisplayChar [可选参数] 替代输入字符的显示字符.
特别值:"" - 直接显示输入字符

返回值

成功: 返回 True
失败: 返回 False设置@error
@error: 101 - $hWnd 参数值不是句柄
102 - $cDisplayChar 不是一个字符

注意/说明

None.

相关

_GUICtrlRichEdit_GetPasswordChar

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    Report("Initial state after creation:")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetPasswordChar($hRichEdit, "*")
                        Report("Changed password character. Type some text")
                    Case 2
                        _GUICtrlRichEdit_SetPasswordChar($hRichEdit, "")
                        Report("Changed it back")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    Local $ch
    $ch = _GUICtrlRichEdit_GetPasswordChar($hRichEdit)
    If $ch = "" Then
        $sMsg &= @CR & "Characters appear as typed"
    Else
        $sMsg = $sMsg & @CR & "Typed characters appear as " & $ch & "s"
    EndIf
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report