函数参考

_GUICtrlRichEdit_SetRECT

设置控件的格式化矩形
译注:原描述文字与 _GUICtrlRichEdit_SetModified 函数完全一样,
参照 _GUICtrlRichEdit_GetRECT 函数汉化此函数的描述文字.

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetRECT($hWnd [,$iLeft = Default [, $iTop = Default [, $iRight = Default [, $iBottom = Default [, $bRedraw = True]]]]]])

参数

$hWnd 控件句柄
$iLeft [可选参数] 对话框左侧位置
$iTop [可选参数] 对话框顶部位置
$iRight [可选参数] 话框右侧位置
$iBottom [可选参数] 对话框底部位置
$bRedraw [可选参数] True, 则强制刷新

返回值

成功: 返回 True
失败: 返回 False设置@error
@error: 101 - $hWnd 参数值不是句柄
1021 - $iLeft 参数值不是正数
1022 - $iTop 参数值不是正数
1023 - $iRight 参数值不是正数
1024 - $iBottom 参数值不是正数
1025 - $iLeft >= $iRight
1026 - $iTop >= $iBottom

注意/说明

 格式化矩形是指绘制文本的区域,其中一部分可能不可见.
 参数的默认值 = 不改变先前值.
 如果只定义 $hWnd, 则被重置为创建时的状态.

相关

_GUICtrlRichEdit_GetRECT

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    _GUICtrlRichEdit_SetText($hRichEdit, "First paragraph")
    _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        Report("1. Default settings ")
                    Case 2
                        _GUICtrlRichEdit_SetRECT($hRichEdit, 10, 10, 100, 100)
                        Report("2. Settings ")
                    Case 3
                        _GUICtrlRichEdit_SetRECT($hRichEdit)
                        Report("3. ReSettings to default")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    Local $aRect = _GUICtrlRichEdit_GetRECT($hRichEdit)
    $sMsg = $sMsg & @CR & @CR & "Left=" & $aRect[0] & " Top=" & $aRect[1] & " Right=" & $aRect[2] & " Bottom=" & $aRect[3]
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report