函数参考

_GUICtrlRichEdit_SetScrollPos

设置滚动起始点 ($ix,$iY) 在控件的左上角

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetScrollPos($hWnd, $iX, $iY)

参数

$hWnd 控件句柄
$iX x 坐标像素值
$iY y 坐标像素值

返回值

成功: 返回 True
失败: 返回 False设置@error
@error: 101 - $hWnd 参数值不是句柄
102 - $iX 不是正数,也不是 0,
103 - $iY 不是正数,也不是 0,

注意/说明

 不会滚动文本到完全离开矩形视图

相关

_GUICtrlRichEdit_GetScrollPos

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    _GUICtrlRichEdit_SetText($hRichEdit, "Paragraph 1")
    For $i = 2 To 20
        _GUICtrlRichEdit_AppendText($hRichEdit, @CRLF & "Paragraph " & $i)
    Next
    Report("0. Initially scrolled to show insertion point")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetScrollPos($hRichEdit, 0, 0)
                        Report("1. Scrolled to top")
                    Case 2
                        _GUICtrlRichEdit_SetScrollPos($hRichEdit, 7, 22)
                        Report("2. Scrolled down a bit, and to the right")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    Local $aPos = _GUICtrlRichEdit_GetScrollPos($hRichEdit)
    $sMsg = $sMsg & @CR & "Get function returns " & $aPos[0] & ";" & $aPos[1]
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report