函数参考

_GUICtrlRichEdit_SetUndoLimit

设置撤消队列可以存储的最大数量

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetUndoLimit($hWnd, $iLimit)

参数

$hWnd 控件句柄
$iLimit 撤消队列中可以存储的最大数量

返回值

成功: 返回 True
失败: 返回 False设置@error
@error: 101 - $hWnd 参数值不是句柄
102 - $iLimit 不是正数,也不是 0,

注意/说明

 要禁用撤消功能, 设置 $iLimit 为 0

 $iLimit 的初始值为 100.

相关

_GUICtrlRichEdit_Undo, _GUICtrlRichEdit_CanRedo, _GUICtrlRichEdit_CanUndo, _GUICtrlRichEdit_GetNextRedo, _GUICtrlRichEdit_Redo

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0, $lblMsg, $hRichEdit
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    _GUICtrlRichEdit_SetText($hRichEdit, "First paragraph")
    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetUndoLimit($hRichEdit, 200)
                        GUICtrlSetData($lblMsg, "Increased the number of actions that can stored in the undo queue from 100 to 200")
                    Case 2
                        _GUICtrlRichEdit_SetUndoLimit($hRichEdit, 0)
                        GUICtrlSetData($lblMsg, "Undo is disabled")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main