函数参考

_GUICtrlRichEdit_StreamFromFile

从文件中设置控件的文本

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_StreamFromFile($hWnd, $sFilespec)

参数

$hWnd 控件句柄
$sFileSpec 文件说明

返回值

成功: 返回 True
失败: 返回 False设置@error
@error: 101 - $hWnd 参数值不是句柄
1021 - 无法打开 $sFilespec 指定的文件
1022 - 文件是空的
700 - 尝试流中字符太多

注意/说明

 如果文本被选中,替换选择的,否则替换控件中所有的文本
 调用 _GUICtrlRichEdit_SetLimitonText 增加控件可以包含文本的字符数

相关

_GUICtrlRichEdit_SetLimitOnText, _GUICtrlRichEdit_StreamFromVar, _GUICtrlRichEdit_StreamToFile

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0, $lblMsg, $hRichEdit
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    _GUICtrlRichEdit_SetText($hRichEdit, "First paragraph")
    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
                        GUICtrlSetData($lblMsg, "Streamed to gcre.rtf")
                    Case 2
                        _GUICtrlRichEdit_SetText($hRichEdit, "")
                        _GUICtrlRichEdit_StreamFromFile($hRichEdit, @DesktopDir & "\gcre.rtf")
                        GUICtrlSetData($lblMsg, "Streamed from gcre.rtf")
                    Case 3
                        _GUICtrlRichEdit_SetSel($hRichEdit, 2, 6)
                        _GUICtrlRichEdit_StreamFromFile($hRichEdit, @DesktopDir & "\gcre.rtf")
                        GUICtrlSetData($lblMsg, "Replaced selection: an intentional mess!")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main