函数参考

_GUICtrlRichEdit_StreamToVar

控件内容写入到变量

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_StreamToVar($hWnd [, $fRtf = True [, $fIncludeCOM=True [, $iOpts=0 [, $iCodePage = 0]]]])

参数

$hWnd 控件句柄
$fRtf [可选参数] True - 写入富文本格式(RTF) (默认)
False - 只写文字
$fIncludeCOM [可选参数] True (default):
如果写 RTF 格式,包括任何 COM 对象(消耗空间)
如果只写文字,写 COM 对象的文本表达
False: 写空格代替 COM 对象
$iOpts [可选参数] 其他选项:
$SFF_PLAINTRTF - 只写入对所有语言普遍适用的关键字
$SF_UNICODE - 写入 Unicode
$iCodePage [可选参数] 生成 UTF-8 和文字使用的代码页
默认 : 没有

返回值

成功: 返回 RTF 或文本
失败: 返回 "" ,设置 @error
@error: 101 - $hWnd 参数值不是句柄
1041 - $SFF_PLAINRTF 是无效的文本文件
1042 - $opts: 是无效的选项
1043 - $SF_UNICODE 仅对文本文件有效
700 - 内部错误

注意/说明

 如果文本被选中,只写选择的,否则全部文本写入到控件

 如果 $sFileSpec 指定扩展名为 .rtf, 则写入 RTF, 否则写纯文本

 调用 _GUICtrlRichEdit_IsModified() 确定文本是否发生了变化

相关

_GUICtrlRichEdit_SetLimitOnText, _GUICtrlRichEdit_StreamFromVar, _GUICtrlRichEdit_StreamToFile

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0, $lblMsg, $hRichEdit, $s
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    _GUICtrlRichEdit_SetText($hRichEdit, "First paragraph")
    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        $s = _GUICtrlRichEdit_StreamToVar($hRichEdit)
                        GUICtrlSetData($lblMsg, "Streamed to variable")
                    Case 2
                        _GUICtrlRichEdit_SetText($hRichEdit, "")
                        _GUICtrlRichEdit_StreamFromVar($hRichEdit, $s)
                        GUICtrlSetData($lblMsg, "Streamed from variable")
                    Case 3
                        _GUICtrlRichEdit_SetSel($hRichEdit, 2, 6)
                        _GUICtrlRichEdit_StreamFromVar($hRichEdit, $s)
                        GUICtrlSetData($lblMsg, "Replaced selection: an intentional mess!")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main