函数参考

_GUICtrlSlider_GetLogicalTics

检索包含滑块刻度逻辑位置的数组

#Include <GuiSlider.au3>
_GUICtrlSlider_GetLogicalTics($hWnd)

参数

$hWnd 控件句柄

返回值

成功: 返回逻辑位置的数组
失败: 设置@error

注意/说明

 数组中元素的个数比 _GUICtrlSlider_GetNumTics 函数返回的刻度数少 2 个.
 请注意, 数组中的值可能包含重复的位置, 且不是按顺序的.
 返回的数组中,数据是有效的,直到您更改滑块的刻度.
 数组元素指定滑块刻度的逻辑位置,不包括创建滑块时的第一个和最后一个刻度.
 滑块最小、最大范围的逻辑位置可以是任意整数值.

相关

示例/演示


#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiSlider.au3>

$Debug_S = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

Global $iMemo

_Main()

Func _Main()
    Local $hSlider, $aTics

    ; 创建 GUI
    GUICreate("Slider Get Logical Tic Positions", 400, 296)
    $hSlider = GUICtrlCreateSlider(2, 2, 300, 20, BitOR($TBS_TOOLTIPS, $TBS_AUTOTICKS))
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    $aTics = _GUICtrlSlider_GetLogicalTics($hSlider)
    MemoWrite("Number Tics Excluding 1st and last .....: " & UBound($aTics))
    For $x = 0 To UBound($aTics) - 1
        MemoWrite(StringFormat("(%02d) Logical Tick Position .............: %d", $x, $aTics[$x]))
    Next

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; 写入一行到 memo 控件
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite