函数参考

_GUICtrlStatusBar_GetBorders

检索水平/垂直边框的当前宽度

#Include <GuiStatusBar.au3>
_GUICtrlStatusBar_GetBorders($hWnd)

参数

$hWnd 控件句柄

返回值

成功: 返回数组的格式如下:
$aBorders[0] - 水平边框宽度
$aBorders[1] - 垂直边框宽度
$aBorders[2] - 矩形中的边框宽度
失败: 设置@error

注意/说明

None.

相关

_GUICtrlStatusBar_GetBordersHorz, _GUICtrlStatusBar_GetBordersRect, _GUICtrlStatusBar_GetBordersVert

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

$Debug_SB = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

Global $iMemo

_Main()

Func _Main()

    Local $hGUI, $aInfo, $hStatus
    Local $aParts[3] = [75, 150, -1]

    ; 创建 GUI
    $hGUI = GUICreate("StatusBar Get Borders", 400, 300)

    $hStatus = _GUICtrlStatusBar_Create($hGUI)
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)

    ; 创建 memo 控件
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Get border sizes
    $aInfo = _GUICtrlStatusBar_GetBorders($hStatus)
    MemoWrite("Horizontal border width .: " & $aInfo[0])
    MemoWrite("Vertical border width ...: " & $aInfo[1])
    MemoWrite("Width between rectangles : " & $aInfo[2])

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; 写入消息到 memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite