函数参考

_GUICtrlStatusBar_IsSimple

检查状态栏控件是否为简单模式

#Include <GuiStatusBar.au3>
_GUICtrlStatusBar_IsSimple($hWnd)

参数

$hWnd 控件句柄

返回值

True: 状态栏是简单模式
False: 状态栏不是简单模式

注意/说明

None.

相关

_GUICtrlStatusBar_SetSimple

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

$Debug_SB = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

Global $iMemo

_Main()

Func _Main()

    Local $hGUI, $hStatus
    Local $aParts[3] = [75, 150, -1]

    ; 创建 GUI
    $hGUI = GUICreate("StatusBar IsSimple", 400, 300)

    $hStatus = _GUICtrlStatusBar_Create($hGUI)
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)

    ; 创建 memo 控件
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Get/Set simple format
    MemoWrite("Simple mode on .: " & _GUICtrlStatusBar_IsSimple($hStatus))
    _GUICtrlStatusBar_SetSimple($hStatus, True)
    MemoWrite("Simple mode on .: " & _GUICtrlStatusBar_IsSimple($hStatus))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; 写入消息到 memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite