函数参考

_GUICtrlTab_SetItemImage

设置标签选项卡图像

#Include <GuiTab.au3>
_GUICtrlTab_SetItemImage($hWnd, $iIndex, $iImage)

参数

$hWnd 控件句柄
$iIndex 标签项目的 0 基索引
$iImage 标签项目图像的 0 基索引

返回值

成功: 返回 True
失败: 返回 False

注意/说明

None.

相关

_GUICtrlTab_GetItemImage

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiTab.au3>
#include <WinAPI.au3>
#include <GuiImageList.au3>

$Debug_TAB = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hGUI, $hImage, $hTab

    ; 创建 GUI
    $hGUI = GUICreate("Tab Control Set Item Image", 400, 300)
    $hTab = GUICtrlCreateTab(2, 2, 396, 296)
    GUISetState()

    ; 创建图像
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 16, 16))
    _GUICtrlTab_SetImageList($hTab, $hImage)

    ; 添加标签
    _GUICtrlTab_InsertItem($hTab, 0, "Tab 1")
    _GUICtrlTab_InsertItem($hTab, 1, "Tab 2")
    _GUICtrlTab_InsertItem($hTab, 2, "Tab 3")

    ; 获取/设置第二个标签的图像
    _GUICtrlTab_SetItemImage($hTab, 1, 1)
    MsgBox(4160, "信息", "Tab 2 image index: " & _GUICtrlTab_GetItemImage($hTab, 1))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main