函数参考

_GUICtrlToolbar_CheckButton

选中或取消选中某个按钮

#Include <GuiToolBar.au3>
_GUICtrlToolbar_CheckButton($hWnd, $iCommandID[, $fCheck = True])

参数

$hWnd 控件句柄
$iCommandID 按钮命令 ID
$fCheck [可选参数] 选择状态:
True - 按钮选中
False - 按钮未选中

返回值

成功: 返回 True
失败: 返回 False

注意/说明

 当按钮被选中时,它会显示在按下状态

相关

示例/演示


#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; 检查传递给函数的类名, 设置为真并使用另一控件的句柄可以看出它是否有效

_Main()

Func _Main()
    Local $hGUI, $hToolbar
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; 创建 GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    GUISetState()

    ; 添加标准系统位图
    _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)

    ; 添加按钮
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; 选中保存按钮
    _GUICtrlToolbar_CheckButton($hToolbar, $idSave)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main