函数参考

_GUICtrlToolbar_EnableButton

启用或禁用指定按钮

#Include <GuiToolBar.au3>
_GUICtrlToolbar_EnableButton($hWnd, $iCommandID[, $fEnable = True])

参数

$hWnd 控件句柄
$iCommandID 按钮命令 ID
$fEnable [可选参数] 可用标志:
True - 启用
False - 禁用

返回值

成功: True
失败: False

注意/说明

None.

相关

_GUICtrlToolbar_HideButton

示例/演示


#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hGUI, $hToolbar
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; 创建 GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    GUISetState()

    ; 添加标准系统位图
    _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)

    ; 添加按钮
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; 禁用帮助按钮
    _GUICtrlToolbar_EnableButton($hToolbar, $idHelp, False)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main