检索按钮信息,返回数据数组.
#Include <GuiToolBar.au3>
_GUICtrlToolbar_GetButtonInfo($hWnd, $iCommandID)
| $hWnd | 控件句柄 |
| $iCommandID | 按钮命令 ID |
| 成功: | 返回数组的格式如下: |
| [0] - 按钮图像 0 基索引索引 | |
| [1] - 按钮状态. 可以是下列值的组合: | |
| $TBSTATE_CHECKED - 按钮被点击 | |
| $TBSTATE_PRESSED - 按钮被点击 | |
| $TBSTATE_ENABLED - 按钮接受用户输入 | |
| $TBSTATE_HIDDEN - 按钮不可见 | |
| $TBSTATE_INDETERMINATE - 按钮呈灰色 | |
| $TBSTATE_WRAP - 按钮之后跟随一个换行符 | |
| $TBSTATE_ELLIPSES - 按钮文本被截断 | |
| $TBSTATE_MARKED - 按钮被标记 | |
| [2] - 按钮样式. 可以是下列值的组合: | |
| $BTNS_AUTOSIZE - 控件不分配标准宽度 | |
| $BTNS_BUTTON - 标准按钮 | |
| $BTNS_CHECK - 双状态推动按钮,在按压与非按压之间切换,按下状态具有不同的背景颜色 | |
| $BTNS_CHECKGROUP - 按钮保持按下,直到另一个按钮被按下 | |
| $BTNS_DROPDOWN - 创建一个下拉式按钮,按钮被点击时,可以显示一个列表. | |
| 代替使用 $WM_COMMAND 消息的按钮,下拉按钮发送 $TBN_DROPDOWN 讯息. | |
| 应用程序通知处理程序显示一个选项列表 | |
| $BTNS_GROUP - 按钮保持按下,直到另一个按钮被按下 | |
| $BTNS_NOPREFIX - 按钮文本没有与它相关的快捷键前缀 | |
| $BTNS_SEP - 创建一个分隔符,提供按钮组之间的小间隙;此样式不接受用户输入 | |
| $BTNS_SHOWTEXT - 按钮应显示指定的文本.所有按钮可以有文字, | |
| 但只有该样式的按钮才能显示文字. | |
| 必须与 $TBSTYLE_LIST 样式与 $TBSTYLE_EX_MIXEDBUTTONS 扩展样式配合使用, | |
| 如果您设置文本的按钮没有这个样式,当鼠标停留时,工具栏控件将自动显示为工具提示, | |
| 这个特征允许您的应用程序避免在工具栏处理 $TBN_GETINFOTIP 消息 | |
| $BTNS_WHOLEDROPDOWN - 指定按钮将有一个下拉箭头 | |
| [3] - 按钮的宽度 | |
| [4] - 按钮参数 |
#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
$Debug_TB = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $hToolbar, $aButton
Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp
; 创建 GUI
$hGUI = GUICreate("Toolbar", 400, 300)
$hToolbar = _GUICtrlToolbar_Create($hGUI)
$iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
GUISetState()
; 添加标准系统位图
Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
Case 0
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
Case 2
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
EndSwitch
; 添加按钮
_GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
_GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
_GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)
; 设置保存按钮信息
_GUICtrlToolbar_SetButtonInfo($hToolbar, $idSave, $STD_PRINT, BitOR($TBSTATE_PRESSED, $TBSTATE_ENABLED), -1, 100, 1234)
; 显示保存按钮信息
$aButton = _GUICtrlToolbar_GetButtonInfo($hToolbar, $idSave)
MemoWrite("Image index ....: " & $aButton[0])
MemoWrite("State flags ....: " & $aButton[1])
MemoWrite("Style flags ....: " & $aButton[2])
MemoWrite("Button width ...: " & $aButton[3])
MemoWrite("Param ..........: " & $aButton[4])
; 循环直到用户退出
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; 写入消息到 memo
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite