函数参考

_GUICtrlToolbar_GetMetrics

检索工具栏控件规格

#Include <GuiToolBar.au3>
_GUICtrlToolbar_GetMetrics($hWnd)

参数

$hWnd 控件句柄

返回值

返回数组的格式如下:
[0] - 工具栏按钮内部的填充宽度
[1] - 工具栏按钮内部的填充高度
[2] - 工具栏按钮之间的空间宽度
[3] - 工具栏按钮之间的空间高度

注意/说明

最低操作系统 - Windows XP.

相关

_GUICtrlToolbar_SetMetrics

示例/演示


#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; 检查传递给函数的类名, 设置为真并使用另一控件的句柄可以看出它是否有效
Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hToolbar, $aMetrics
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; 创建 GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
    GUISetState()

    ; 添加标准系统位图
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; 添加按钮
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    GUISetState(@SW_LOCK)
    ; 设置控件度量
    _GUICtrlToolbar_SetMetrics($hToolbar, 1, 2, 3, 4)
    GUISetState(@SW_UNLOCK)

    ; 显示控件度量
    $aMetrics = _GUICtrlToolbar_GetMetrics($hToolbar)
    MemoWrite("Button padding width ...: " & $aMetrics[0])
    MemoWrite("Button padding height ..: " & $aMetrics[1])
    MemoWrite("Button spacing width ...: " & $aMetrics[2])
    MemoWrite("Button spacing height ..: " & $aMetrics[3])

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; 写入消息到 memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite