函数参考

_GUICtrlToolbar_GetStyle

检索工具栏的样式

#Include <GuiToolBar.au3>
_GUICtrlToolbar_GetStyle($hWnd)

参数

$hWnd 控件句柄

返回值

成功: 返回控件样式. 可以是下列的组合:
$TBSTYLE_TOOLTIPS - 创建工具提示控件
$TBSTYLE_WRAPABLE - 创建按钮工具栏,可以有多行
$TBSTYLE_ALTDRAG - 允许用户通过拖动改变工具栏按钮的位置
$TBSTYLE_FLAT - 创建一个平面工具栏
$TBSTYLE_LIST - 创建一个按钮文本在右边的平面工具栏
$TBSTYLE_CUSTOMERASE - 处理 $WM_ERASEBKGND 消息时发送 $NM_CUSTOMDRAW
$TBSTYLE_REGISTERDROP - 发送 $TBN_GETOBJECT 消息到拖放目标对象
$TBSTYLE_TRANSPARENT - 创建透明的工具栏

注意/说明

None.

相关

_GUICtrlToolbar_SetStyle

示例/演示


#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; 检查传递给函数的类名, 设置为真并使用另一控件的句柄可以看出它是否有效
Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hToolbar
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; 创建 GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
    GUISetState()

    ; 设置控件样式
    _GUICtrlToolbar_SetStyle($hToolbar, BitOR($TBSTYLE_LIST, $CCS_TOP))

    ; 添加标准系统位图
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; 添加按钮
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; 显示控件样式
    MemoWrite("Toolbar style .: 0x" & Hex(_GUICtrlToolbar_GetStyle($hToolbar)))


    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; 写入消息到 memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite