函数参考

_GUICtrlToolbar_InsertMarkHitTest

检索点的插入标记信息

#Include <GuiToolBar.au3>
_GUICtrlToolbar_InsertMarkHitTest($hWnd, $iX, $iY)

参数

$hWnd 控件句柄
$iX 相对于客户区 X 位置
$iY 相对于客户区 Y 位置

返回值

成功: 返回数组的格式如下:
[0] - 插入标记的 0 基索引,或 -1,为没有插入标记
[1] - 定义插入位置.可以是以下值之一:
0 - 在左边
1 - 在右边
2 - 在工具栏的背景

注意/说明

None.

相关

示例/演示


#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作
Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hToolbar, $aStrings[4], $aRect, $aMark
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; 创建 GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
    GUISetState()

    ; 添加标准系统位图
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; 添加字符串
    $aStrings[0] = _GUICtrlToolbar_AddString($hToolbar, "&New Button")
    $aStrings[1] = _GUICtrlToolbar_AddString($hToolbar, "&Open Button")
    $aStrings[2] = _GUICtrlToolbar_AddString($hToolbar, "&Save Button")
    $aStrings[3] = _GUICtrlToolbar_AddString($hToolbar, "&Help Button")

    ; 添加按钮
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW, $aStrings[0])
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN, $aStrings[1])
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE, $aStrings[2])
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP, $aStrings[3])

    ; Set insert mark
    _GUICtrlToolbar_SetInsertMark($hToolbar, 1, 1)

    ; Do insert mark hit test 1
    $aMark = _GUICtrlToolbar_InsertMarkHitTest($hToolbar, 0, 0)
    MemoWrite("Index ........: " & $aMark[0])
    MemoWrite("Relationship .: " & $aMark[1])

    ; Do insert mark hit test 2
    $aRect = _GUICtrlToolbar_GetButtonRect($hToolbar, $idSave)
    $aMark = _GUICtrlToolbar_InsertMarkHitTest($hToolbar, $aRect[0], $aRect[1])
    MemoWrite("Index ........: " & $aMark[0])
    MemoWrite("Relationship .: " & $aMark[1])

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; 写入消息到 memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite