函数参考

_GUICtrlToolbar_LoadImages

加载系统定义的按钮图像到工具栏控件的图像列表

#Include <GuiToolBar.au3>
_GUICtrlToolbar_LoadImages($hWnd, $iBitMapID)

参数

$hWnd 控件句柄
$iBitMapID 系统定义按钮图像列表标识符.可以设置为以下值之一:
$IDB_HIST_LARGE_COLOR
$IDB_HIST_SMALL_COLOR
$IDB_STD_LARGE_COLOR
$IDB_STD_SMALL_COLOR
$IDB_VIEW_LARGE_COLOR
$IDB_VIEW_SMALL_COLOR
$IDB_HIST_NORMAL
$IDB_HIST_HOT
$IDB_HIST_DISABLED
$IDB_HIST_PRESSED

返回值

成功: 返回图像列表中的图像数,不包括那些刚添加
失败: 返回 0

注意/说明

None.

相关

示例/演示


#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; 检查传递给函数的类名, 设置为真并使用另一控件的句柄可以看出它是否有效

_Main()

Func _Main()
    Local $hGUI, $hToolbar, $aStrings[4]
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; 创建 GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    GUISetState()

    ; 添加标准系统位图
    _GUICtrlToolbar_SetBitmapSize($hToolbar, 24, 24)
    _GUICtrlToolbar_LoadImages($hToolbar, $IDB_STD_LARGE_COLOR)

    ; 添加字符串
    $aStrings[0] = _GUICtrlToolbar_AddString($hToolbar, "&New Button")
    $aStrings[1] = _GUICtrlToolbar_AddString($hToolbar, "&Open Button")
    $aStrings[2] = _GUICtrlToolbar_AddString($hToolbar, "&Save Button")
    $aStrings[3] = _GUICtrlToolbar_AddString($hToolbar, "&Help Button")

    ; 添加按钮
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW, $aStrings[0])
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN, $aStrings[1])
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE, $aStrings[2])
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP, $aStrings[3])

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main