函数参考

_GUICtrlToolbar_SetButtonState

设置按钮的状态信息

#Include <GuiToolBar.au3>
_GUICtrlToolbar_SetButtonState($hWnd, $iCommandID, $iState)

参数

$hWnd 控件句柄
$iCommandID 按钮命令 ID
$iState 返回按钮的状态.可以是一或多个下列值::
$TBSTATE_CHECKED - 按钮有 $TBSTYLE_CHECK 样式并被点击
$TBSTATE_PRESSED - 按钮被点击
$TBSTATE_ENABLED - 按钮接受用户输入
$TBSTATE_HIDDEN - 按钮不可见,且不能接收用户输入
$TBSTATE_INDETERMINATE - 按钮呈灰色
$TBSTATE_WRAP - 按钮之后跟随一个换行符
$TBSTATE_ELLIPSES - 按钮文本被截断,并显示一个省略号
$TBSTATE_MARKED - 按钮被标记

返回值

成功: 返回 True
失败: 返回 False

注意/说明

None.

相关

_GUICtrlToolbar_GetButtonState

示例/演示


#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作
Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hToolbar
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; 创建 GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
    GUISetState()

    ; 添加标准系统位图
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; 添加按钮
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Show Save button state
    MemoWrite("Save button state: " & _GUICtrlToolbar_GetButtonState($hToolbar, $idSave))

    Sleep(1000)

    ; Set Save button state
    Local $bool = _GUICtrlToolbar_SetButtonState($hToolbar, $idSave, BitOR($TBSTATE_ENABLED, $TBSTATE_PRESSED))
    MemoWrite("Set button state: " & $bool)

    ; Show Save button state
    MemoWrite("Save button state: " & _GUICtrlToolbar_GetButtonState($hToolbar, $idSave))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; 写入消息到 memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite