函数参考

_GUICtrlToolbar_SetButtonStyle

设置按钮的样式标志

#Include <GuiToolBar.au3>
_GUICtrlToolbar_SetButtonStyle($hWnd, $iCommandID, $iStyle)

参数

$hWnd 控件句柄
$iCommandID 按钮命令 ID
$iStyle 按钮样式. 可以是一或多个下列值:
$BTNS_AUTOSIZE - 工具栏控件应不分配标准宽度到按钮.
按钮宽度将计算文本加上图像的宽度
$BTNS_CHECK - 双状态推动按钮,在按压与非按压之间切换,
按下状态具有不同的背景颜色
$BTNS_CHECKGROUP - 按下的按钮保持到另一组中的按钮被按下为止,
类似选项按钮,相当于 $BTNS_CHECK 与 $BTNS_GROUP 的结合
$BTNS_DROPDOWN - 下拉式按钮,显示一个下拉列表
$BTNS_GROUP - 按下的按钮保持到另一组中的按钮被按下为止,
类似选项按钮,相当于 $BTNS_CHECK 与 $BTNS_GROUP 的结合
$BTNS_NOPREFIX - 按钮文本没有与它相关的快捷键前缀
$BTNS_SEP - 分隔符
$BTNS_SHOWTEXT - 显示按钮文本
$BTNS_WHOLEDROPDOWN - 按钮有下拉箭头

返回值

成功: 返回 True
失败: 返回 False

注意/说明

None.

相关

_GUICtrlToolbar_GetButtonStyle

示例/演示


#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; 检查传递给函数的类名, 设置为真并使用另一控件的句柄可以看出它是否有效
Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hToolbar
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; 创建 GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
    GUISetState()

    ; 添加标准系统位图
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; 添加按钮
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; 设置保存按钮样式
    _GUICtrlToolbar_SetButtonStyle($hToolbar, $idSave, $BTNS_CHECK)

    ; 显示保存按钮样式
    MemoWrite("Save button style: " & _GUICtrlToolbar_GetButtonStyle($hToolbar, $idSave))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; 写入消息到 memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite