函数参考

_GUICtrlTreeView_DisplayRect

返回树项目矩形,返回数据数组.

#include <GuiTreeView.au3>
_GUICtrlTreeView_DisplayRect($hWnd, $hItem [, $fTextOnly = False])

参数

$hWnd 控件句柄
$hItem 项目句柄
$fTextOnly [可选参数] 如为 True, 矩形只包括项目的文本
否则.包括整个项目占有行

返回值

成功: 返回数组的格式如下:
$aRect[0] - 矩形左上角 X 坐标
$aRect[1] - 矩形左上角 Y 坐标
$aRect[2] - 矩形右下角 X 坐标
$aRect[3] - 矩形右下角 Y 坐标
失败: 设置@error

注意/说明

None.

相关

_GUICtrlTreeView_DisplayRectEx

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()

    Local $hItem[6], $hImage, $aRect, $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Display Rect", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
    _GUICtrlTreeView_SetNormalImageList($hTreeView, $hImage)

    For $x = 0 To _GUIImageList_GetImageCount($hImage) - 1
        $hItem[$x] = _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] New Item", $x + 1), $x, $x)
    Next
    $aRect = _GUICtrlTreeView_DisplayRect($hTreeView, $hItem[2])
    MsgBox(4160, "信息", StringFormat("Item 2 Rectangle : [%d, %d, %d, %d]", $aRect[0], $aRect[1], $aRect[2], $aRect[3]))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main