函数参考

_GUICtrlTreeView_EnsureVisible

确保项目可见,展开父项目或必要时滚动项目.

#include <GuiTreeView.au3>
_GUICtrlTreeView_EnsureVisible($hWnd, $hItem)

参数

$hWnd 控件ID/句柄
$hItem 项目句柄

返回值

True: 树视图控件没有可供系统滚动的展开项目
False: 其它

注意/说明

None.

相关

_GUICtrlTreeView_GetVisible

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()

    Local $hItem[100], $iRand, $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS)

    GUICreate("TreeView Ensure Visible", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To 99
        $hItem[$x] = _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] New Item", $x))
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    $iRand = Random(40, 99, 1)
    MsgBox(4160, "信息", StringFormat("Index %d Visible: %s", $iRand, _GUICtrlTreeView_GetVisible($hTreeView, $hItem[$iRand])))
    _GUICtrlTreeView_EnsureVisible($hTreeView, $hItem[$iRand])
    MsgBox(4160, "信息", StringFormat("Index %d Visible: %s", $iRand, _GUICtrlTreeView_GetVisible($hTreeView, $hItem[$iRand])))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main