函数参考

_GUICtrlTreeView_GetFirstChild

检索指定项目的第一个子项

#include <GuiTreeView.au3>
_GUICtrlTreeView_GetFirstChild($hWnd, $hItem)

参数

$hWnd 控件ID/句柄
$hItem 项目句柄

返回值

成功: 返回第一子项句柄
失败: 返回 0

注意/说明

None.

相关

_GUICtrlTreeView_GetLastChild, _GUICtrlTreeView_GetNextChild, _GUICtrlTreeView_GetPrevChild

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()

    Local $hItem[6], $hRandomItem, $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Get First Child", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To UBound($hItem) - 1
        $hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $hTreeView)
        For $y = 0 To 2
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $y), $hItem[$x])
        Next
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    $hRandomItem = Random(0, UBound($hItem) - 1, 1)
    MsgBox(4160, "信息", StringFormat("Item %d First Shild? %s", $hRandomItem, _GUICtrlTreeView_GetFirstChild($hTreeView, $hItem[$hRandomItem])))
    _GUICtrlTreeView_SelectItem($hTreeView, _GUICtrlTreeView_GetFirstChild($hTreeView, $hItem[$hRandomItem]))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main