函数参考

_GUICtrlTreeView_GetState

检索项目状态

#include <GuiTreeView.au3>
_GUICtrlTreeView_GetState($hWnd [, $hItem = 0])

参数

$hWnd 控件ID/句柄
$hItem [可选参数] 项目 ID/句柄

返回值

成功: 返回项目的状态
失败: 设置@error

注意/说明

None.

相关

_GUICtrlTreeView_SetState

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()

    Local $hItem[10], $iRand, $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Get State", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To 9
        $hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $hTreeView)
        For $y = 1 To Random(2, 10, 1)
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Child", $y), $hItem[$x])
        Next
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    $iRand = Random(0, 9, 1)
    _GUICtrlTreeView_SetSelected($hTreeView, $hItem[$iRand])
    MsgBox(4160, "信息", StringFormat("State for Index %d? %s", $iRand, _GUICtrlTreeView_GetState($hTreeView, $hItem[$iRand])))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main