函数参考

_GUICtrlTreeView_GetVisibleCount

检索控件中显示完全可见的项目最大数

#include <GuiTreeView.au3>
_GUICtrlTreeView_GetVisibleCount($hWnd)

参数

$hWnd 控件ID/句柄

返回值

返回控件显示可见项目的最大数

注意/说明

 最大可见项目数可以大于控件现有项目数.
 最大值是控件计算客户端窗口高度除以一个项目高度的结果值.
 请注意,返回值是控件允许完全可见的项目数.(不是项目的实际数)
 如果你能看到项目 20 及其以后的一部分,返回值是 20,而不是 21

相关

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()

    Local $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS)

    GUICreate("TreeView Get Visible Count", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To 99
        _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] New Item", $x))
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    MsgBox(4160, "信息", "Visible: " & _GUICtrlTreeView_GetVisibleCount($hTreeView))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main