函数参考

_GUICtrlTreeView_SetDropTarget

设置项目为拖放目标

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetDropTarget($hWnd, $hItem [, $fFlag = True])

参数

$hWnd 控件ID/句柄
$hItem 项目句柄
$fFlag [可选参数] 设置标志:
 True - 项目为拖放目标
False - 项目不是拖放目标

返回值

成功: True
失败: False

注意/说明

None.

相关

_GUICtrlTreeView_GetDropTarget

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; 检查传递给函数的类名, 设置为真并使用另一控件的句柄可以看出它是否有效

_Main()

Func _Main()

    Local $hItem[6], $hRandomItem, $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Set Drop Target", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To UBound($hItem) - 1
        $hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x + 1), $hTreeView)
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    $hRandomItem = Random(0, UBound($hItem) - 1, 1)
    MsgBox(4160, "信息", StringFormat("Item %d Drop Target? %s", $hRandomItem, _GUICtrlTreeView_GetDropTarget($hTreeView, $hItem[$hRandomItem])))
    _GUICtrlTreeView_SetDropTarget($hTreeView, $hItem[$hRandomItem])
    MsgBox(4160, "信息", StringFormat("Item %d Drop Target? %s", $hRandomItem, _GUICtrlTreeView_GetDropTarget($hTreeView, $hItem[$hRandomItem])))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main