函数参考

_GUICtrlTreeView_SetIndent

设置树视图控件的缩进宽度

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetIndent($hWnd, $iIndent)

参数

$hWnd 控件ID/句柄
$iIndent 缩进宽度的像素值

返回值

None.

注意/说明

如果 $iIndent 参数值小于系统定义的最小宽度,
则新宽度设置为系统定义的最小宽度

相关

_GUICtrlTreeView_GetIndent

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()

    Local $hImage, $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Set Indent", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
    _GUICtrlTreeView_SetNormalImageList($hTreeView, $hImage)

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To _GUIImageList_GetImageCount($hImage) - 1
        _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] New Item", $x + 1), $x, $x)
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    MsgBox(4160, "信息", "Indent: " & _GUICtrlTreeView_GetIndent($hTreeView))

    _GUICtrlTreeView_SetIndent($hTreeView, 25)

    MsgBox(4160, "信息", "Indent: " & _GUICtrlTreeView_GetIndent($hTreeView))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main